Mercurial > cgi-bin > hgwebdir.cgi > PR > Applications > VSs > VSs__H264__App

annotate libavcodec/arm/vp3dsp_neon.S @ 9:ea1ba68cf0ed

find changesets by author, revision, files, or words in the commit message
update to match api changes + add sscc produced source
author Nina Engelhardt <nengel@mailbox.tu-berlin.de>
date Wed, 05 Jun 2013 14:43:26 +0200
parents
children
rev   line source
nengel@2 1 /*
nengel@2 2 * Copyright (c) 2009 David Conrad
nengel@2 3 *
nengel@2 4 * This file is part of FFmpeg.
nengel@2 5 *
nengel@2 6 * FFmpeg is free software; you can redistribute it and/or
nengel@2 7 * modify it under the terms of the GNU Lesser General Public
nengel@2 8 * License as published by the Free Software Foundation; either
nengel@2 9 * version 2.1 of the License, or (at your option) any later version.
nengel@2 10 *
nengel@2 11 * FFmpeg is distributed in the hope that it will be useful,
nengel@2 12 * but WITHOUT ANY WARRANTY; without even the implied warranty of
nengel@2 13 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
nengel@2 14 * Lesser General Public License for more details.
nengel@2 15 *
nengel@2 16 * You should have received a copy of the GNU Lesser General Public
nengel@2 17 * License along with FFmpeg; if not, write to the Free Software
nengel@2 18 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
nengel@2 19 */
nengel@2 20
nengel@2 21 #include "asm.S"
nengel@2 22
nengel@2 23 .section .rodata
nengel@2 24 .align 4
nengel@2 25
nengel@2 26 vp3_idct_constants:
nengel@2 27 .short 64277, 60547, 54491, 46341, 36410, 25080, 12785
nengel@2 28
nengel@2 29 #define xC1S7 d0[0]
nengel@2 30 #define xC2S6 d0[1]
nengel@2 31 #define xC3S5 d0[2]
nengel@2 32 #define xC4S4 d0[3]
nengel@2 33 #define xC5S3 d1[0]
nengel@2 34 #define xC6S2 d1[1]
nengel@2 35 #define xC7S1 d1[2]
nengel@2 36
nengel@2 37 .text
nengel@2 38
nengel@2 39 .macro vp3_loop_filter
nengel@2 40 vsubl.u8 q3, d18, d17
nengel@2 41 vsubl.u8 q2, d16, d19
nengel@2 42 vadd.i16 q1, q3, q3
nengel@2 43 vadd.i16 q2, q2, q3
nengel@2 44 vadd.i16 q0, q1, q2
nengel@2 45 vrshr.s16 q0, q0, #3
nengel@2 46 vmovl.u8 q9, d18
nengel@2 47 vdup.u16 q15, r2
nengel@2 48
nengel@2 49 vabs.s16 q1, q0
nengel@2 50 vshr.s16 q0, q0, #15
nengel@2 51 vqsub.u16 q2, q15, q1
nengel@2 52 vqsub.u16 q3, q2, q1
nengel@2 53 vsub.i16 q1, q2, q3
nengel@2 54 veor q1, q1, q0
nengel@2 55 vsub.i16 q0, q1, q0
nengel@2 56
nengel@2 57 vaddw.u8 q2, q0, d17
nengel@2 58 vsub.i16 q3, q9, q0
nengel@2 59 vqmovun.s16 d0, q2
nengel@2 60 vqmovun.s16 d1, q3
nengel@2 61 .endm
nengel@2 62
nengel@2 63 function ff_vp3_v_loop_filter_neon, export=1
nengel@2 64 sub ip, r0, r1
nengel@2 65 sub r0, r0, r1, lsl #1
nengel@2 66 vld1.64 {d16}, [r0,:64], r1
nengel@2 67 vld1.64 {d17}, [r0,:64], r1
nengel@2 68 vld1.64 {d18}, [r0,:64], r1
nengel@2 69 vld1.64 {d19}, [r0,:64], r1
nengel@2 70 ldrb r2, [r2, #129*4]
nengel@2 71
nengel@2 72 vp3_loop_filter
nengel@2 73
nengel@2 74 vst1.64 {d0}, [ip,:64], r1
nengel@2 75 vst1.64 {d1}, [ip,:64], r1
nengel@2 76 bx lr
nengel@2 77 endfunc
nengel@2 78
nengel@2 79 function ff_vp3_h_loop_filter_neon, export=1
nengel@2 80 sub ip, r0, #1
nengel@2 81 sub r0, r0, #2
nengel@2 82 vld1.32 {d16[]}, [r0], r1
nengel@2 83 vld1.32 {d17[]}, [r0], r1
nengel@2 84 vld1.32 {d18[]}, [r0], r1
nengel@2 85 vld1.32 {d19[]}, [r0], r1
nengel@2 86 vld1.32 {d16[1]}, [r0], r1
nengel@2 87 vld1.32 {d17[1]}, [r0], r1
nengel@2 88 vld1.32 {d18[1]}, [r0], r1
nengel@2 89 vld1.32 {d19[1]}, [r0], r1
nengel@2 90 ldrb r2, [r2, #129*4]
nengel@2 91
nengel@2 92 vtrn.8 d16, d17
nengel@2 93 vtrn.8 d18, d19
nengel@2 94 vtrn.16 d16, d18
nengel@2 95 vtrn.16 d17, d19
nengel@2 96
nengel@2 97 vp3_loop_filter
nengel@2 98
nengel@2 99 vtrn.8 d0, d1
nengel@2 100
nengel@2 101 vst1.16 {d0[0]}, [ip], r1
nengel@2 102 vst1.16 {d1[0]}, [ip], r1
nengel@2 103 vst1.16 {d0[1]}, [ip], r1
nengel@2 104 vst1.16 {d1[1]}, [ip], r1
nengel@2 105 vst1.16 {d0[2]}, [ip], r1
nengel@2 106 vst1.16 {d1[2]}, [ip], r1
nengel@2 107 vst1.16 {d0[3]}, [ip], r1
nengel@2 108 vst1.16 {d1[3]}, [ip], r1
nengel@2 109 bx lr
nengel@2 110 endfunc
nengel@2 111
nengel@2 112
nengel@2 113 function vp3_idct_start_neon
nengel@2 114 vpush {d8-d15}
nengel@2 115 movrel r3, vp3_idct_constants
nengel@2 116 vld1.64 {d0-d1}, [r3,:128]
nengel@2 117 vld1.64 {d16-d19}, [r2,:128]!
nengel@2 118 vld1.64 {d20-d23}, [r2,:128]!
nengel@2 119 vld1.64 {d24-d27}, [r2,:128]!
nengel@2 120 vadd.s16 q1, q8, q12
nengel@2 121 vsub.s16 q8, q8, q12
nengel@2 122 vld1.64 {d28-d31}, [r2,:128]!
nengel@2 123 endfunc
nengel@2 124
nengel@2 125 function vp3_idct_core_neon
nengel@2 126 vmull.s16 q2, d18, xC1S7 // (ip[1] * C1) << 16
nengel@2 127 vmull.s16 q3, d19, xC1S7
nengel@2 128 vmull.s16 q4, d2, xC4S4 // ((ip[0] + ip[4]) * C4) << 16
nengel@2 129 vmull.s16 q5, d3, xC4S4
nengel@2 130 vmull.s16 q6, d16, xC4S4 // ((ip[0] - ip[4]) * C4) << 16
nengel@2 131 vmull.s16 q7, d17, xC4S4
nengel@2 132 vshrn.s32 d4, q2, #16
nengel@2 133 vshrn.s32 d5, q3, #16
nengel@2 134 vshrn.s32 d6, q4, #16
nengel@2 135 vshrn.s32 d7, q5, #16
nengel@2 136 vshrn.s32 d8, q6, #16
nengel@2 137 vshrn.s32 d9, q7, #16
nengel@2 138 vadd.s16 q12, q1, q3 // E = (ip[0] + ip[4]) * C4
nengel@2 139 vadd.s16 q8, q8, q4 // F = (ip[0] - ip[4]) * C4
nengel@2 140 vadd.s16 q1, q2, q9 // ip[1] * C1
nengel@2 141
nengel@2 142 vmull.s16 q2, d30, xC1S7 // (ip[7] * C1) << 16
nengel@2 143 vmull.s16 q3, d31, xC1S7
nengel@2 144 vmull.s16 q4, d30, xC7S1 // (ip[7] * C7) << 16
nengel@2 145 vmull.s16 q5, d31, xC7S1
nengel@2 146 vmull.s16 q6, d18, xC7S1 // (ip[1] * C7) << 16
nengel@2 147 vmull.s16 q7, d19, xC7S1
nengel@2 148 vshrn.s32 d4, q2, #16
nengel@2 149 vshrn.s32 d5, q3, #16
nengel@2 150 vshrn.s32 d6, q4, #16 // ip[7] * C7
nengel@2 151 vshrn.s32 d7, q5, #16
nengel@2 152 vshrn.s32 d8, q6, #16 // ip[1] * C7
nengel@2 153 vshrn.s32 d9, q7, #16
nengel@2 154 vadd.s16 q2, q2, q15 // ip[7] * C1
nengel@2 155 vadd.s16 q9, q1, q3 // A = ip[1] * C1 + ip[7] * C7
nengel@2 156 vsub.s16 q15, q4, q2 // B = ip[1] * C7 - ip[7] * C1
nengel@2 157
nengel@2 158 vmull.s16 q2, d22, xC5S3 // (ip[3] * C5) << 16
nengel@2 159 vmull.s16 q3, d23, xC5S3
nengel@2 160 vmull.s16 q4, d22, xC3S5 // (ip[3] * C3) << 16
nengel@2 161 vmull.s16 q5, d23, xC3S5
nengel@2 162 vmull.s16 q6, d26, xC5S3 // (ip[5] * C5) << 16
nengel@2 163 vmull.s16 q7, d27, xC5S3
nengel@2 164 vshrn.s32 d4, q2, #16
nengel@2 165 vshrn.s32 d5, q3, #16
nengel@2 166 vshrn.s32 d6, q4, #16
nengel@2 167 vshrn.s32 d7, q5, #16
nengel@2 168 vshrn.s32 d8, q6, #16
nengel@2 169 vshrn.s32 d9, q7, #16
nengel@2 170 vadd.s16 q3, q3, q11 // ip[3] * C3
nengel@2 171 vadd.s16 q4, q4, q13 // ip[5] * C5
nengel@2 172 vadd.s16 q1, q2, q11 // ip[3] * C5
nengel@2 173 vadd.s16 q11, q3, q4 // C = ip[3] * C3 + ip[5] * C5
nengel@2 174
nengel@2 175 vmull.s16 q2, d26, xC3S5 // (ip[5] * C3) << 16
nengel@2 176 vmull.s16 q3, d27, xC3S5
nengel@2 177 vmull.s16 q4, d20, xC2S6 // (ip[2] * C2) << 16
nengel@2 178 vmull.s16 q5, d21, xC2S6
nengel@2 179 vmull.s16 q6, d28, xC6S2 // (ip[6] * C6) << 16
nengel@2 180 vmull.s16 q7, d29, xC6S2
nengel@2 181 vshrn.s32 d4, q2, #16
nengel@2 182 vshrn.s32 d5, q3, #16
nengel@2 183 vshrn.s32 d6, q4, #16
nengel@2 184 vshrn.s32 d7, q5, #16
nengel@2 185 vshrn.s32 d8, q6, #16 // ip[6] * C6
nengel@2 186 vshrn.s32 d9, q7, #16
nengel@2 187 vadd.s16 q2, q2, q13 // ip[5] * C3
nengel@2 188 vadd.s16 q3, q3, q10 // ip[2] * C2
nengel@2 189 vsub.s16 q13, q2, q1 // D = ip[5] * C3 - ip[3] * C5
nengel@2 190 vsub.s16 q1, q9, q11 // (A - C)
nengel@2 191 vadd.s16 q11, q9, q11 // Cd = A + C
nengel@2 192 vsub.s16 q9, q15, q13 // (B - D)
nengel@2 193 vadd.s16 q13, q15, q13 // Dd = B + D
nengel@2 194 vadd.s16 q15, q3, q4 // G = ip[2] * C2 + ip[6] * C6
nengel@2 195
nengel@2 196 vmull.s16 q2, d2, xC4S4 // ((A - C) * C4) << 16
nengel@2 197 vmull.s16 q3, d3, xC4S4
nengel@2 198 vmull.s16 q4, d28, xC2S6 // (ip[6] * C2) << 16
nengel@2 199 vmull.s16 q5, d29, xC2S6
nengel@2 200 vmull.s16 q6, d20, xC6S2 // (ip[2] * C6) << 16
nengel@2 201 vmull.s16 q7, d21, xC6S2
nengel@2 202 vshrn.s32 d4, q2, #16
nengel@2 203 vshrn.s32 d5, q3, #16
nengel@2 204 vshrn.s32 d6, q4, #16
nengel@2 205 vshrn.s32 d7, q5, #16
nengel@2 206 vshrn.s32 d8, q6, #16 // ip[2] * C6
nengel@2 207 vmull.s16 q5, d18, xC4S4 // ((B - D) * C4) << 16
nengel@2 208 vmull.s16 q6, d19, xC4S4
nengel@2 209 vshrn.s32 d9, q7, #16
nengel@2 210 vadd.s16 q3, q3, q14 // ip[6] * C2
nengel@2 211 vadd.s16 q10, q1, q2 // Ad = (A - C) * C4
nengel@2 212 vsub.s16 q14, q4, q3 // H = ip[2] * C6 - ip[6] * C2
nengel@2 213 bx lr
nengel@2 214 endfunc
nengel@2 215
nengel@2 216 .macro VP3_IDCT_END type
nengel@2 217 function vp3_idct_end_\type\()_neon
nengel@2 218 .ifc \type, col
nengel@2 219 vdup.16 q0, r3
nengel@2 220 vadd.s16 q12, q12, q0
nengel@2 221 vadd.s16 q8, q8, q0
nengel@2 222 .endif
nengel@2 223
nengel@2 224 vshrn.s32 d2, q5, #16
nengel@2 225 vshrn.s32 d3, q6, #16
nengel@2 226 vadd.s16 q2, q12, q15 // Gd = E + G
nengel@2 227 vadd.s16 q9, q1, q9 // (B - D) * C4
nengel@2 228 vsub.s16 q12, q12, q15 // Ed = E - G
nengel@2 229 vsub.s16 q3, q8, q10 // Fd = F - Ad
nengel@2 230 vadd.s16 q10, q8, q10 // Add = F + Ad
nengel@2 231 vadd.s16 q4, q9, q14 // Hd = Bd + H
nengel@2 232 vsub.s16 q14, q9, q14 // Bdd = Bd - H
nengel@2 233 vadd.s16 q8, q2, q11 // [0] = Gd + Cd
nengel@2 234 vsub.s16 q15, q2, q11 // [7] = Gd - Cd
nengel@2 235 vadd.s16 q9, q10, q4 // [1] = Add + Hd
nengel@2 236 vsub.s16 q10, q10, q4 // [2] = Add - Hd
nengel@2 237 vadd.s16 q11, q12, q13 // [3] = Ed + Dd
nengel@2 238 vsub.s16 q12, q12, q13 // [4] = Ed - Dd
nengel@2 239 .ifc \type, row
nengel@2 240 vtrn.16 q8, q9
nengel@2 241 .endif
nengel@2 242 vadd.s16 q13, q3, q14 // [5] = Fd + Bdd
nengel@2 243 vsub.s16 q14, q3, q14 // [6] = Fd - Bdd
nengel@2 244
nengel@2 245 .ifc \type, row
nengel@2 246 // 8x8 transpose
nengel@2 247 vtrn.16 q10, q11
nengel@2 248 vtrn.16 q12, q13
nengel@2 249 vtrn.16 q14, q15
nengel@2 250 vtrn.32 q8, q10
nengel@2 251 vtrn.32 q9, q11
nengel@2 252 vtrn.32 q12, q14
nengel@2 253 vtrn.32 q13, q15
nengel@2 254 vswp d17, d24
nengel@2 255 vswp d19, d26
nengel@2 256 vadd.s16 q1, q8, q12
nengel@2 257 vswp d21, d28
nengel@2 258 vsub.s16 q8, q8, q12
nengel@2 259 vswp d23, d30
nengel@2 260 .endif
nengel@2 261 bx lr
nengel@2 262 endfunc
nengel@2 263 .endm
nengel@2 264
nengel@2 265 VP3_IDCT_END row
nengel@2 266 VP3_IDCT_END col
nengel@2 267
nengel@2 268 function ff_vp3_idct_neon, export=1
nengel@2 269 mov ip, lr
nengel@2 270 mov r2, r0
nengel@2 271 bl vp3_idct_start_neon
nengel@2 272 bl vp3_idct_end_row_neon
nengel@2 273 mov r3, #8
nengel@2 274 bl vp3_idct_core_neon
nengel@2 275 bl vp3_idct_end_col_neon
nengel@2 276 mov lr, ip
nengel@2 277 vpop {d8-d15}
nengel@2 278
nengel@2 279 vshr.s16 q8, q8, #4
nengel@2 280 vshr.s16 q9, q9, #4
nengel@2 281 vshr.s16 q10, q10, #4
nengel@2 282 vshr.s16 q11, q11, #4
nengel@2 283 vshr.s16 q12, q12, #4
nengel@2 284 vst1.64 {d16-d19}, [r0,:128]!
nengel@2 285 vshr.s16 q13, q13, #4
nengel@2 286 vshr.s16 q14, q14, #4
nengel@2 287 vst1.64 {d20-d23}, [r0,:128]!
nengel@2 288 vshr.s16 q15, q15, #4
nengel@2 289 vst1.64 {d24-d27}, [r0,:128]!
nengel@2 290 vst1.64 {d28-d31}, [r0,:128]!
nengel@2 291 bx lr
nengel@2 292 endfunc
nengel@2 293
nengel@2 294 function ff_vp3_idct_put_neon, export=1
nengel@2 295 mov ip, lr
nengel@2 296 bl vp3_idct_start_neon
nengel@2 297 bl vp3_idct_end_row_neon
nengel@2 298 mov r3, #8
nengel@2 299 add r3, r3, #2048 // convert signed pixel to unsigned
nengel@2 300 bl vp3_idct_core_neon
nengel@2 301 bl vp3_idct_end_col_neon
nengel@2 302 mov lr, ip
nengel@2 303 vpop {d8-d15}
nengel@2 304
nengel@2 305 vqshrun.s16 d0, q8, #4
nengel@2 306 vqshrun.s16 d1, q9, #4
nengel@2 307 vqshrun.s16 d2, q10, #4
nengel@2 308 vqshrun.s16 d3, q11, #4
nengel@2 309 vst1.64 {d0}, [r0,:64], r1
nengel@2 310 vqshrun.s16 d4, q12, #4
nengel@2 311 vst1.64 {d1}, [r0,:64], r1
nengel@2 312 vqshrun.s16 d5, q13, #4
nengel@2 313 vst1.64 {d2}, [r0,:64], r1
nengel@2 314 vqshrun.s16 d6, q14, #4
nengel@2 315 vst1.64 {d3}, [r0,:64], r1
nengel@2 316 vqshrun.s16 d7, q15, #4
nengel@2 317 vst1.64 {d4}, [r0,:64], r1
nengel@2 318 vst1.64 {d5}, [r0,:64], r1
nengel@2 319 vst1.64 {d6}, [r0,:64], r1
nengel@2 320 vst1.64 {d7}, [r0,:64], r1
nengel@2 321 bx lr
nengel@2 322 endfunc
nengel@2 323
nengel@2 324 function ff_vp3_idct_add_neon, export=1
nengel@2 325 mov ip, lr
nengel@2 326 bl vp3_idct_start_neon
nengel@2 327 bl vp3_idct_end_row_neon
nengel@2 328 mov r3, #8
nengel@2 329 bl vp3_idct_core_neon
nengel@2 330 bl vp3_idct_end_col_neon
nengel@2 331 mov lr, ip
nengel@2 332 vpop {d8-d15}
nengel@2 333 mov r2, r0
nengel@2 334
nengel@2 335 vld1.64 {d0}, [r0,:64], r1
nengel@2 336 vshr.s16 q8, q8, #4
nengel@2 337 vld1.64 {d1}, [r0,:64], r1
nengel@2 338 vshr.s16 q9, q9, #4
nengel@2 339 vld1.64 {d2}, [r0,:64], r1
nengel@2 340 vaddw.u8 q8, q8, d0
nengel@2 341 vld1.64 {d3}, [r0,:64], r1
nengel@2 342 vaddw.u8 q9, q9, d1
nengel@2 343 vld1.64 {d4}, [r0,:64], r1
nengel@2 344 vshr.s16 q10, q10, #4
nengel@2 345 vld1.64 {d5}, [r0,:64], r1
nengel@2 346 vshr.s16 q11, q11, #4
nengel@2 347 vld1.64 {d6}, [r0,:64], r1
nengel@2 348 vqmovun.s16 d0, q8
nengel@2 349 vld1.64 {d7}, [r0,:64], r1
nengel@2 350 vqmovun.s16 d1, q9
nengel@2 351 vaddw.u8 q10, q10, d2
nengel@2 352 vaddw.u8 q11, q11, d3
nengel@2 353 vshr.s16 q12, q12, #4
nengel@2 354 vshr.s16 q13, q13, #4
nengel@2 355 vqmovun.s16 d2, q10
nengel@2 356 vqmovun.s16 d3, q11
nengel@2 357 vaddw.u8 q12, q12, d4
nengel@2 358 vaddw.u8 q13, q13, d5
nengel@2 359 vshr.s16 q14, q14, #4
nengel@2 360 vshr.s16 q15, q15, #4
nengel@2 361 vst1.64 {d0}, [r2,:64], r1
nengel@2 362 vqmovun.s16 d4, q12
nengel@2 363 vst1.64 {d1}, [r2,:64], r1
nengel@2 364 vqmovun.s16 d5, q13
nengel@2 365 vst1.64 {d2}, [r2,:64], r1
nengel@2 366 vaddw.u8 q14, q14, d6
nengel@2 367 vst1.64 {d3}, [r2,:64], r1
nengel@2 368 vaddw.u8 q15, q15, d7
nengel@2 369 vst1.64 {d4}, [r2,:64], r1
nengel@2 370 vqmovun.s16 d6, q14
nengel@2 371 vst1.64 {d5}, [r2,:64], r1
nengel@2 372 vqmovun.s16 d7, q15
nengel@2 373 vst1.64 {d6}, [r2,:64], r1
nengel@2 374 vst1.64 {d7}, [r2,:64], r1
nengel@2 375 bx lr
nengel@2 376 endfunc
nengel@2 377
nengel@2 378 function ff_vp3_idct_dc_add_neon, export=1
nengel@2 379 ldrsh r2, [r2]
nengel@2 380 movw r3, #46341
nengel@2 381 mul r2, r3, r2
nengel@2 382 smulwt r2, r3, r2
nengel@2 383 mov r3, r0
nengel@2 384 vdup.16 q15, r2
nengel@2 385 vrshr.s16 q15, q15, #4
nengel@2 386
nengel@2 387 vld1.8 {d0}, [r0,:64], r1
nengel@2 388 vld1.8 {d1}, [r0,:64], r1
nengel@2 389 vld1.8 {d2}, [r0,:64], r1
nengel@2 390 vaddw.u8 q8, q15, d0
nengel@2 391 vld1.8 {d3}, [r0,:64], r1
nengel@2 392 vaddw.u8 q9, q15, d1
nengel@2 393 vld1.8 {d4}, [r0,:64], r1
nengel@2 394 vaddw.u8 q10, q15, d2
nengel@2 395 vld1.8 {d5}, [r0,:64], r1
nengel@2 396 vaddw.u8 q11, q15, d3
nengel@2 397 vld1.8 {d6}, [r0,:64], r1
nengel@2 398 vaddw.u8 q12, q15, d4
nengel@2 399 vld1.8 {d7}, [r0,:64], r1
nengel@2 400 vaddw.u8 q13, q15, d5
nengel@2 401 vqmovun.s16 d0, q8
nengel@2 402 vaddw.u8 q14, q15, d6
nengel@2 403 vqmovun.s16 d1, q9
nengel@2 404 vaddw.u8 q15, q15, d7
nengel@2 405 vqmovun.s16 d2, q10
nengel@2 406 vst1.8 {d0}, [r3,:64], r1
nengel@2 407 vqmovun.s16 d3, q11
nengel@2 408 vst1.8 {d1}, [r3,:64], r1
nengel@2 409 vqmovun.s16 d4, q12
nengel@2 410 vst1.8 {d2}, [r3,:64], r1
nengel@2 411 vqmovun.s16 d5, q13
nengel@2 412 vst1.8 {d3}, [r3,:64], r1
nengel@2 413 vqmovun.s16 d6, q14
nengel@2 414 vst1.8 {d4}, [r3,:64], r1
nengel@2 415 vqmovun.s16 d7, q15
nengel@2 416 vst1.8 {d5}, [r3,:64], r1
nengel@2 417 vst1.8 {d6}, [r3,:64], r1
nengel@2 418 vst1.8 {d7}, [r3,:64], r1
nengel@2 419 bx lr
nengel@2 420 endfunc